EXCEL数字转英语公式
发布网友
共3个回答
热心网友
1.新建如图所示的Excel表格，把A列中的数字用英文的形式转换到B列中。
2.按住“Alt+F11”打开VBA编辑器，如图所示。
3. 在VBA编辑器中单击菜单栏“插入”——模块，如图所示。
4.在打开的模块中输入如下代码：
Option Explicit
Function 数字转英文(ByVal MyNumber)
Dim Dollars, Cents, Temp
Dim DecimalPlace, Count
ReDim Place(9) As String
Place(2) = " Thousand "
Place(3) = " Million "
Place(4) = " Billion "
Place(5) = " Trillion "
MyNumber = Trim(Str(MyNumber))
DecimalPlace = InStr(MyNumber, ".")
If DecimalPlace > 0 Then
Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
"00", 2))
MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
End If
Count = 1
Do While MyNumber <> ""
Temp = GetHundreds(Right(MyNumber, 3))
If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
If Len(MyNumber) > 3 Then
MyNumber = Left(MyNumber, Len(MyNumber) - 3)
Else
MyNumber = ""
End If
Count = Count + 1
Loop
Select Case Dollars
Case ""
Dollars = "No Dollars"
Case "One"
Dollars = "One Dollar"
Case Else
Dollars = Dollars & " Dollars"
End Select
Select Case Cents
Case ""
Cents = " and No Cents"
Case "One"
Cents = " and One Cent"
Case Else
Cents = " and " & Cents & " Cents"
End Select
数字转英文 = Dollars & Cents
End Function
Function GetHundreds(ByVal MyNumber)
Dim Result As String
If Val(MyNumber) = 0 Then Exit Function
MyNumber = Right("000" & MyNumber, 3)
If Mid(MyNumber, 1, 1) <> "0" Then
Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
End If
If Mid(MyNumber, 2, 1) <> "0" Then
Result = Result & GetTens(Mid(MyNumber, 2))
Else
Result = Result & GetDigit(Mid(MyNumber, 3))
End If
GetHundreds = Result
End Function
Function GetTens(TensText)
Dim Result As String
Result = ""
If Val(Left(TensText, 1)) = 1 Then
Select Case Val(TensText)
Case 10: Result = "Ten"
Case 11: Result = "Eleven"
Case 12: Result = "Twelve"
Case 13: Result = "Thirteen"
Case 14: Result = "Fourteen"
Case 15: Result = "Fifteen"
Case 16: Result = "Sixteen"
Case 17: Result = "Seventeen"
Case 18: Result = "Eighteen"
Case 19: Result = "Nineteen"
Case Else
End Select
Else
Select Case Val(Left(TensText, 1))
Case 2: Result = "Twenty "
Case 3: Result = "Thirty "
Case 4: Result = "Forty "
Case 5: Result = "Fifty "
Case 6: Result = "Sixty "
Case 7: Result = "Seventy "
Case 8: Result = "Eighty "
Case 9: Result = "Ninety "
Case Else
End Select
Result = Result & GetDigit _
(Right(TensText, 1))
End If
GetTens = Result
End Function
Function GetDigit(Digit)
Select Case Val(Digit)
Case 1: GetDigit = "One"
Case 2: GetDigit = "Two"
Case 3: GetDigit = "Three"
Case 4: GetDigit = "Four"
Case 5: GetDigit = "Five"
Case 6: GetDigit = "Six"
Case 7: GetDigit = "Seven"
Case 8: GetDigit = "Eight"
Case 9: GetDigit = "Nine"
Case Else: GetDigit = ""
End Select
End Function
5.调用函数：
现在回到Excel表格中，单击“B1”单元格，在菜单栏选择“插入”——函数。
6.在打开的“插入函数”对话框的“或选择类别”中选择“用户定义”，然后选择函数“数字转英文”，单击“确定”按钮。
7.在打开的“函数参数”对话框中输入“A1”，单击“确定”按钮。
8.然后用填充手柄向下填充公式，现在就可以看到转换好的英文了。
热心网友
把下面的宏放在模块中,就可以在 Excel 中用.
比如说输入公式: =NumToEng(1234) 会得出: One Thousand Two Hundred Thirty Four
(只能是整数,因为小数涉及到不同单位,不同说法的问题,如元角分)
Function NumToEng(Num)
Num = Int(Num)
Dim Tri(5) As String
Tri(1) = ""
Tri(2) = " Thousand "
Tri(3) = " Million "
Tri(4) = " Billion "
Tri(5) = " Trillion "
NumToEng = ""
Txt = Trim(Str(Num))
Count = 1
Do While Txt <> ""
Tmp = Get000(Num000:=Val(Right(Txt, 3)))
If Tmp <> "" Then NumToEng = Tmp & Tri(Count) & NumToEng
If Len(Txt) > 3 Then Txt = Left(Txt, Len(Txt) - 3) Else Txt = ""
Count = Count + 1
Loop
End Function
Function Get000(Num000 As Integer)
Get000 = ""
Text000 = WorksheetFunction.Text(Num000, "000")
If Left(Text000, 1) <> "0" Then Get000 = Get0(Num0:=Val(Left(Text000, 1))) & " Hundred "
Get000 = Get000 & Get00(Num00:=Val(Right(Text000, 2)))
End Function
Function Get00(Num00 As Integer)
Get00 = ""
Text00 = WorksheetFunction.Text(Num00, "00")
If Val(Left(Text00, 1)) = 1 Then
Select Case Num00
Case 10: Get00 = "Ten"
Case 11: Get00 = "Eleven"
Case 12: Get00 = "Twelve"
Case 13: Get00 = "Thirteen"
Case 14: Get00 = "Fourteen"
Case 15: Get00 = "Fifteen"
Case 16: Get00 = "Sixteen"
Case 17: Get00 = "Seventeen"
Case 18: Get00 = "Eighteen"
Case 19: Get00 = "Nineteen"
Case Else
End Select
Else
Select Case Val(Left(Text00, 1))
Case 2: Get00 = "Twenty "
Case 3: Get00 = "Thirty "
Case 4: Get00 = "Forty "
Case 5: Get00 = "Fifty "
Case 6: Get00 = "Sixty "
Case 7: Get00 = "Seventy "
Case 8: Get00 = "Eighty "
Case 9: Get00 = "Ninety "
Case Else
End Select
Get00 = Get00 & Get0(Num0:=Val(Right(Text00, 1)))
End If
End Function
Function Get0(Num0 As Integer)
Select Case Val(Num0)
Case 1: Get0 = "One"
Case 2: Get0 = "Two"
Case 3: Get0 = "Three"
Case 4: Get0 = "Four"
Case 5: Get0 = "Five"
Case 6: Get0 = "Six"
Case 7: Get0 = "Seven"
Case 8: Get0 = "Eight"
Case 9: Get0 = "Nine"
Case Else: Get0 = ""
End Select
End Function
热心网友
建议你登陆 club.excelhome.net 搜索
