如何实现两台主机之间的通信
发布网友
发布时间：2022-04-22 16:15
共2个回答
热心网友
时间：2023-08-24 01:16
VB用winsock控件吧，网上例子太多了，你也可以看看书
用Winsock实现点对点通信
作者不详
Winsock控件是VB5.0的新增功能,它解决了以往应用VB编程时网络中应用程序之间无法实现点对点通信的难题。Winsock使用的TCP协议和UDP协议允许建立并保持一个到远程计算机上的连接,且可以在连接结束之前实时地进行数据交换。用户仅通过设置属性并借助事件处理就能够轻而易举地连接到一个远程的计 算机上,而且只用两个命令就可以实现数据交换。
使用TCP协议时,如果需要创建一个客户应用程序,就必须识别服务器的名称或IP地址。
应用程序的通信端口随时都将仔细监测对方发出的消息,这是系统进行可靠连接的保证。一旦连接发生,任何一方都可以通过SendData发送和接收数据,并借助GetData把自己的数据分离出来。传送数据时,需要先设定客户机的LocalPort属性,服务器则只需要把RemoteHost属性设定为客户机以太网的地址,并设定与客户机LocalPort属性相同的端口地址, 借助SendData方法开始发送消息。客户机则在GetData事件中通过DataArrival事件分离出发送的信息。
一个Winsock控件可以让本地计算机连接到远程的计算机上,同时使用UDP或TCP协议,两个协议都能创建客户机和服务器应用。
使用Winsock控件时,通信的双方需要选定相同的协议。TCP协议适用于传送大容量、需要安全性保证的数据文件;而UDP协议适用于需要分别与很多下属通信,或者建立的连接比较多且为时变的情况,特别是在数据量很小的时候。设定时可以使用Winsock1.Protocol =
sckTCPProtocol方法,首先要找到你的计算机的名称,并把它添入Winsock的LocalHost属性中。
创建一个应用程序时,首先要确定你建立的是客户方应用还是服务器服务,只有建立的服务器应用开始工作,并进入监听状态时,客户应用程序才开始建立连接,进入正常的通信状态。笔者建立了一个应用程序,它的功能是当客户方的鼠标移动时,服务器应用程序上能够实时显示该鼠标的位置。下面是建立服务器应用的方法:
1.创建一个新的标准EXE文件;
2.加入一个Winsock控件;
3.加入如下代码:
Private Sub Form Load()
tcpServer.LocalPort = 1001
tcpServer.Localhost = 〃servser〃
tcpServer.remotePort = 1002
tcpServer.Localhost = 〃klint〃
tcpServer.Listen
End Sub
′连接检查
Private Sub tcpServer ConnectionRequest
(ByVal requestID As Long)
If tcpServer.State <> sckClosed Then
tcpServer.Close
tcpServer.Accept requestID
End Sub
′发送数据
Private Sub frmserver monsemove(x,y)
tcpServer.SendData 〃x〃& str(x)
tcpServer.SendData 〃y〃& str(y)
End Sub
建立客户应用的方法为:
1.创建一个新的标准EXE文件;
2.加入一个Winsock控件;
3.加入两个TEXT框—— txt x和 txt y;
4.加入如下代码:
Private Sub Form Load()
tcpServer.LocalPort = 1002
tcpServer.Localhost = 〃klint〃
tcpServer.remotePort = 1001
tcpServer.Localhost = 〃servser〃
tcpServer.Listen
End Sub
′连接检查
Private Sub tcpklint ConnectionRequest
(ByVal requestID As Long)
If tcpklint.State <> sckClosed Then
tcpklint.Close
tcpklint.Accept requestID
End Sub
Private Sub tcpClient DataArrival
(ByVal bytesTotal As Long)
Dim strData As String
tcpklint.GetData strData
if left(strData,1)=〃X〃then
txt x.Text = strData
else
txt y.Text = strData
endif
End Sub
以上例程实现的是一个非常简单的点对点通信,在此基础上略加改造,可以形成功能复杂的实时计算机网络A-A交互通信系统,用于控制、图形仿真等。
使用UDP协议建立对等通信和通过TCP建立客户/服务器通信的方法略有不同,它不需要建立客户和服务器,而是建立对等通信。此过程通过以下几步实现:
1.设定Winsock的RemoteHost 属性为一个通信的计算机名称;
2.设定 RemotePort 为一个接口号;
3.调用Winsock的Bind 事件绑定本地的接口号。具体设定方法为:
Private Sub Form Load()
With Winsock1
.RemoteHost= 〃PeerB〃
.RemotePort = 1001 ′远程连接号
.Bind 1002
′绑定的本地号
End With
End Sub
程序的其它部分与TCP方法类似,即通过SendData 和GetData 方法发送或提取数据。UDP和TCP协 议在使用中各有特点,如果灵活使用,可以得到很好的效果。令人欣慰的是,VB5.0 中Winsock给我们提供了一种简便的数据传送方法,使我们得以轻松地实现网络点对点通信。
参考资料：http://www.hqsm.com/article/net/net021.htm
热心网友
时间：2023-08-24 01:17
用VB5中WinSock控件编写网上聊天程序
Sockets是在Unix系统上提出来的，一开始主要是用于本地通讯，但很快就应用到C/S体系上。MicroSoft公司在此基础上创建了WinSock控件，专门用于Windows接口，与Sockets完全兼容。Winsock控件对用户来说是不可见的，它提供了访问 TCP 和 UDP 网络服务的方便途径。Microsoft Access、Visual Basic、Visual C++ 或 Visual FoxPro 的开发人员都可使用它。为编写客户或服务器应用程序，不必了解 TCP 的细节或调用低级的 Winsock APIs。通过设置控件的属性并调用其方法就可轻易连接到一台远程机器上去，并且还可双向交换数据。下面就利用VB5中的WinSock控件编写一个网上聊天程序。
一）网络通信协议的基础和选择
1．1 TCP（数据传输协议）基础
数据传输协议允许创建和维护与远程计算机的连接。连接两台计算机就可彼此进行数据传输。
如果创建客户应用程序，就必须知道服务器计算机名或者 IP 地址（RemoteHost 属性），还要知道进行“侦听”的端口（RemotePort 属性），然后调用 Connect 方法。
如果创建服务器应用程序，就应设置一个收听端口（LocalPort 属性）并调用 Listen 方法。当客户计算机需要连接时就会发生 ConnectionRequest 事件。为了完成连接，可调用 ConnectionRequest 事件内的 Accept 方法。
建立连接后，任何一方计算机都可以收发数据。为了发送数据，可调用 SendData 方法。当接收数据时会发生 DataArrival 事件。调用 DataArrival 事件内的 GetData 方法就可获取数据。
1．2 UDP（用户数据文报协议）基础
用户数据文报协议 (UDP) 是一个无连接协议。跟 TCP 的操作不同，计算机并不建立连接。另外 UDP 应用程序可以是客户机，也可以是服务器。
为了传输数据，首先要设置客户计算机的 LocalPort 属性。然后，服务器计算机只需将 RemoteHost 设置为客户计算机的 Internet 地址，并将 RemotePort 属性设置为跟客户计算机的 LocalPort 属性相同的端口，并调用 SendData 方法来着手发送信息。于是，客户计算机使用 DataArrival 事件内的 GetData 方法来获取已发送的信息。
1．3 选择通讯协议
在使用 WinSock 控件时，首先需要考虑使用什么协议。可以使用的协议包括 TCP 和 UDP。两种协议之间的重要区别在于它们的连接状态：
TCP 协议是有连接的协议，可以将它同电话系统相比。在开始数据传输之前，用户必须先建立连接。
UDP 协议是一种无连接协议，两台计算机之间的传输类似于传递邮件：消息从一台计算机发送到另一台计算机，但是两者之间没有明确的连接。另外，单次传输的最大数据量取决于具体的网络。
到底选择哪一种协议通常是由需要创建的应用程序决定的。下面的几个问题将有助于选择适宜的协议：
1. 在收发数据的时候，应用程序是否需要得到客户端或者服务器的确认信息？如果需要，使用 TCP 协议，在收发数据之前先建立明确的连接。
2. 数据量是否特别大（例如图象与声音文件）？在连接建立之后，TCP 协议将维护连接并确保数据的完整性。不过，这种连接需要更多的计算资源，因而是比较“昂贵”的。
3. 数据发送是间歇的，还是在一个会话内？例如，如果应用程序在某个任务完成的时候需要通知某个计算机，UDP 协议是更适宜的。UDP 协议适合发送少量的数据。
通讯协议的选择是通过设置WinSock的Protocol属性来实现的。下面选择TCP通讯协议编写网上聊天程序，在此之前必须知道一个极其重要的参数---服务器端的IP地址或计算机名。
二）确定计算机的名字
1. 在计算机的桌面上，右键单击“网上邻居”。
2. 选择“属性”。
3. 单击“标识”选项卡。
4. 在“计算机名称”框中可以找到计算机的名称。
确定计算机的 IP地址
1. 单击“任务条”上的“启动”。
2. 选择“运行”。
3. 若服务器端操作系统为win95则在“打开”中填入“winipcfg”，若服务器端操作系统为winnt则在“打开”中填入“ipconfig”。
4. 按下“确定”键。
上面找到的计算机名称或IP地址可以作为WinSock的RemoteHost 属性的值。
三） winsock控件的State属性。
state 属性的设置值是： 常 数
值 描 述
sckclosed 0 缺省的。关闭
sckopen 1 打开
scklistening 2 侦听
sckconnectionpending 3 连接挂起
sckresolvinghost 4 识别主机
sckhostresolved 5 已识别主机
sckconnecting 6 正在连接
sckconnected 7 已连接
sckclosing 8 同级人员正在关闭连接
sckerror 9 错误
下面主要要用到sckClosed.sckConnected两个State属性的值。
四）网上聊天程序的编制
4．1 程序中服务器端所起的作用。
从图示中可以看到服务器端的两个winsock控件之间并不存在直接的通讯，同时sckServer1和sckClient2及sckServer2和sckClient1之间是不能直接通讯的。这也即是说若sckClient1向sckClient2发出信息，信息首先被sckServer1接受，sckServer1再将信息传给程序的信息处理部分，信息处理部分再将处理好的信息传给sckServer2，再由sckServer2传给sckClient2。反之亦然。那么服务器端的信息处理部分又进行什么工作呢？
1. 对通讯的通道数作一些*。
2. 对使用后已关闭的通道，必须能够重新使用以节省资源。
3. 必须对所传递的数据包信息作甑别，从而作出不同的处理。
通过解开数据的包头就可区分不同的信息。
网上聊天有两种方式：第一种，以广播方式；第二种，以点对点的方式。广播方式即所有客户都能收到某一客户发出的信息。点对点的方式即想说“悄悄话”的一对客户专门开辟了一间谈话的“小屋”，别的客户不能“听”到他们的谈话。在下面的程序中将看到如何利用数据的不同包头来区分用户是想以广播方式还是以点对点的方式进行谈话的（点对点方式数据的包头为“PT”,广播方式则无包头）。
4．2 客户端的程序
1. 在客户端创建一个新的工程将其命名为“ClientPrj”
2. 将缺省窗体命名为 frmClient。
3. 将窗体的标题改为“Client”。
4. 在窗体中添加一个 WinSock 控件，并将其命名为 tcpClient。
5. 在 frmClient 中添加一个ListBox 控件。将其命名为lstReceive。
6. 在 frmClient 中添加一个 TextBox 控件。将其命名为 txtSend。
7. 在窗体上放两个 CommandButton 控件，并将其命名为 cmdConnect和cmdSent。
8. 将cmdConnect控件的标题改为 Connect, 将cmdSent控件的标题改为 Sent。
9. 在窗体中添加如下的代码。
Private Sub cmdConnect_Click()
On Error GoTo ErrorPro
sckClient.Connect
Exit Sub
ErrorPro:
MsgBox "服务器未开或网络出错！"
End
End Sub
Private Sub cmdSent_Click()
sckClient.SendData txtSent.Text
End Sub
Private Sub Form_Load()
' RemoteComputerName为服务器端的计算机名或IP地址。
sckClient.RemoteHost = "RemoteComputerName"
sckClient.RemotePort = 1000
End Sub
Private Sub sckClient_Close()
MsgBox "服务器通道已关闭！"
End
End Sub
Private Sub sckClient_Connect()
MsgBox "连接成功！"
cmdConnect.Enabled = False
End Sub
Private Sub sckClient_DataArrival(ByVal bytesTotal As Long)
Dim s As String
sckClient.GetData s
lstReceive.AddItem s
End Sub
Private Sub sckClient_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, _ ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
sckClient.Close
cmdConnect.Enabled = True
End Sub
4．3 服务器端的程序
1. 在服务器端创建一个新的工程将其命名为“ServerPrj”。
2. 将缺省窗体命名为“frmServer”。
3. 在窗体中添加一个ListBox控件，将其命名为“lstReceive”。
4. 在窗体中添加三个WinSock控件，将其分别命名为“sckListen”，sckBusy和“sckServer”并将“sckServer”的“Index”属性设置为0。
5. 在窗体中添加如下代码.。
'最大通道数
Private MaxChan As Integer
Private Sub Form_Load()
Dim i As Integer
MaxChan = 10
For i = 1 To MaxChan - 1
Load sckServer(i)
Next i
sckListen.LocalPort = 1000
sckListen.Listen
End Sub
Private Sub sckBusy_Close()
sckBusy.Close
End Sub
Private Sub sckBusy_DataArrival(ByVal bytesTotal As Long)
sckBusy.SendData "服务器忙，请稍后再连接！"
DoEvents
End Sub
Private Sub sckListen_ConnectionRequest(ByVal requestID As Long)
Dim i As Integer
'决定由哪一Winsock接受请求
For i = 0 To MaxChan - 1
If sckServer(i).State = 0 Then
Exit For
End If
Next i
If sckServer(i).State = 0 Then
sckServer(i).Accept requestID
Exit Sub
End If
'如果所有Winsock都用完则由专门的“忙”Winsock接受请求，以免用户要求得不到响应
sckBusy.Close
sckBusy.Accept requestID
End Sub
Private Sub sckListen_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, _ ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
sckListen.Close
sckListen.LocalPort = 1000
sckListen.Listen
End Sub
Private Sub sckServer_Close(Index As Integer)
sckServer(Index).Close
End Sub
Private Sub sckServer_DataArrival(Index As Integer, ByVal bytesTotal As Long)
Dim s As String
Dim i As Integer
sckServer(Index).GetData s
If UCase(Left(Trim(s), 2)) = "PT" Then '判断是否为悄悄话，点对点方式
If IsNumeric(Mid(Trim(s), 3, 1)) Then
i = Mid(Trim(s), 3, 1)
sckServer(i).SendData "Channel " & Index & " " & Right(Trim(s), Len(Trim(s)) - 3)
DoEvents
End If
Else '广播方式
For i = 0 To MaxChan - 1
'利用winsock的State属性给所有连接在服务器上的客户发消息
If sckServer(i).State = 7 Then
sckServer(i).SendData "Channel " & Index & " " & Trim(s)
DoEvents
End If
Next i
End If
lstReceive.AddItem "Channel " & Index & " " & Trim(s)
End Sub
Private Sub sckServer_Error(Index As Integer, ByVal Number As Integer, Description As String, _
ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As _
Long, CancelDisplay As Boolean)
sckServer(Index).Close
End Sub
从程序中可以看到：第一，程序中*了通道数（10路）。第二，通过判断WinSock控件的State属性是否为0（关闭状态），来重新使用已关闭的WinSock控件。第三，通过给WinSock控件传递的信息加上包头，来对信息进行不同的处理（程序中若信息前加上了“PT"（Private Talk）+"通道数”的包头，由此就知道客户想要同拥有此“通道数”的另一客户进行“悄悄话”，否则就以广播方式将信息发给所有客户）。
五） 结束语
WinSock控件不仅仅是用来编制网上聊天程序，而且可以用来编制各种网络游戏或网络通信程序。实际上WinSock控件是编制各种C/S程序的利器。在实际使用中通常是将WinSock控件封装在Activex DLL（进程内）、Activex EXE（进程外）部件的类中（类中引用）来使用的。通过区分所传信息前的不同的包头，用RaiseEvent命令引发不同 的事件，再对事件分别进行处理。这样不仅增加了程序的可调试性和安全性，而且更符合事件驱动编程方法的特点。
